home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
mac
/
LOGIC Apple II 5.25" Library - ProDOS
/
PRO001.dsk
/
DG.DEMO1.bas
< prev
next >
Wrap
BASIC Source File
|
2012-02-16
|
2KB
|
63 lines
100 REM 16-COLOR DEMO 1
110 REM APPLE ORCHARD FEB 1984
120 REM MODS BY KEITH FALKNER
130 REM SES (COMPUTING) INC.
140 GOTO 270
150 REM CIRCLE SUBROUTINE
160 X0 = X0 +MX:Y0 = Y0 +MY
170 FOR CX = 0 TO R -1
180 CY = SQR(R *R -CX *CX)
190 PX = CX +CX
200 & DOT AT X0 -PX,Y0 -CY
210 & LINE TO X0 -PX,Y0 +CY
220 & DOT AT X0 +PX,Y0 -CY
230 & LINE TO X0 +PX,Y0 +CY
240 NEXT
250 RETURN
260 REM VERIFY APPLE //E
270 IF PEEK( -1101) = 6 GOTO 300
280 M$ = "THIS REQUIRES AN APPLE //E.": GOTO 370
290 REM IS PGM IN HIRES MEMORY?
300 IF PEEK(104) >63 GOTO 340
310 IF PEEK(176) <32 THEN LOMEM: 16384: GOTO 340
320 M$ = "PROGRAM OCCUPIES HI-RES MEMORY.": GOTO 370
330 REM VERIFY DG.INIT WAS RUN
340 IF PEEK(104) >8 GOTO 390
350 M$ = "PLEASE RUN DG.INIT FIRST."
360 REM FATAL ERROR. STOP
370 TEXT : HOME : PRINT M$: STOP : NEW
380 REM DOUBLE-GRAPHIC INIT
390 PRINT CHR$(4)"PR#3"
400 & DG: & BRUSH
410 X0 = 0:Y0 = 0
420 CX = CY = PX = QX = 0
430 REM CONSTANTS
440 SX = 27:SY = 13.5
450 DX = 3 *SX:DY = 3 *SY
460 MX = 275:FX = 555
470 MY = 96:FY = 191
480 REM DRAW CIRCLES
490 X0 = 0:Y0 = 0
500 & HUE = 10
510 R = DX
520 GOSUB 160
530 X0 = 0:Y0 = 0
540 & HUE = 15
550 R = DY
560 GOSUB 160
570 REM DRAW COLOR CHIPS
580 FOR I = 1 TO 12
590 READ C,NX,NY
600 X0 = NX *DX
610 Y0 = NY *DY
620 R = SY
630 & HUE = C
640 GOSUB 160
650 NEXT
660 POKE 49168,0: WAIT 49152,128: POKE 49168,0: PRINT CHR$(4)"PR#3"
670 PRINT CHR$(21): PRINT CHR$(4)"PR#0"
680 TEXT : HOME : END
690 REM DATA: COLOR, NX, NY
700 DATA 1,0,-2,8,-2,0,2,2,0,4,0,2
710 DATA 9,-1.07,-1.07,3,1.07,-1.07,12,-1.07,1.07,6,1.07,1.07
720 DATA 11,0,-.95,13,-.95,0,7,.95,0,14,0,.95