home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS / PRO001.dsk / DG.DEMO1.bas < prev    next >
BASIC Source File  |  2012-02-16  |  2KB  |  63 lines
  1. 100  REM  16-COLOR DEMO 1
  2. 110  REM APPLE ORCHARD FEB 1984
  3. 120  REM MODS BY KEITH FALKNER
  4. 130  REM SES (COMPUTING) INC.
  5. 140  GOTO 270
  6. 150  REM CIRCLE SUBROUTINE
  7. 160 X0 = X0 +MX:Y0 = Y0 +MY
  8. 170  FOR CX = 0 TO R -1
  9. 180 CY =  SQR(R *R -CX *CX)
  10. 190 PX = CX +CX
  11. 200  & DOT AT X0 -PX,Y0 -CY
  12. 210  & LINE TO X0 -PX,Y0 +CY
  13. 220  & DOT AT X0 +PX,Y0 -CY
  14. 230  & LINE TO X0 +PX,Y0 +CY
  15. 240  NEXT 
  16. 250  RETURN 
  17. 260  REM VERIFY APPLE //E
  18. 270  IF  PEEK( -1101) = 6 GOTO 300
  19. 280 M$ = "THIS REQUIRES AN APPLE //E.": GOTO 370
  20. 290  REM IS PGM IN HIRES MEMORY?
  21. 300  IF  PEEK(104) >63 GOTO 340
  22. 310  IF  PEEK(176) <32  THEN  LOMEM: 16384: GOTO 340
  23. 320 M$ = "PROGRAM OCCUPIES HI-RES MEMORY.": GOTO 370
  24. 330  REM VERIFY DG.INIT WAS RUN
  25. 340  IF  PEEK(104) >8 GOTO 390
  26. 350 M$ = "PLEASE RUN DG.INIT FIRST."
  27. 360  REM FATAL ERROR. STOP
  28. 370  TEXT : HOME : PRINT M$: STOP : NEW 
  29. 380  REM DOUBLE-GRAPHIC INIT
  30. 390  PRINT  CHR$(4)"PR#3"
  31. 400  & DG: & BRUSH
  32. 410 X0 = 0:Y0 = 0
  33. 420 CX = CY = PX = QX = 0
  34. 430  REM CONSTANTS
  35. 440 SX = 27:SY = 13.5
  36. 450 DX = 3 *SX:DY = 3 *SY
  37. 460 MX = 275:FX = 555
  38. 470 MY = 96:FY = 191
  39. 480  REM DRAW CIRCLES
  40. 490 X0 = 0:Y0 = 0
  41. 500  & HUE = 10
  42. 510 R = DX
  43. 520  GOSUB 160
  44. 530 X0 = 0:Y0 = 0
  45. 540  & HUE = 15
  46. 550 R = DY
  47. 560  GOSUB 160
  48. 570  REM DRAW COLOR CHIPS
  49. 580  FOR I = 1 TO 12
  50. 590  READ C,NX,NY
  51. 600 X0 = NX *DX
  52. 610 Y0 = NY *DY
  53. 620 R = SY
  54. 630  & HUE = C
  55. 640  GOSUB 160
  56. 650  NEXT 
  57. 660  POKE 49168,0: WAIT 49152,128: POKE 49168,0: PRINT  CHR$(4)"PR#3"
  58. 670  PRINT  CHR$(21): PRINT  CHR$(4)"PR#0"
  59. 680  TEXT : HOME : END 
  60. 690  REM DATA: COLOR, NX, NY
  61. 700  DATA 1,0,-2,8,-2,0,2,2,0,4,0,2
  62. 710  DATA 9,-1.07,-1.07,3,1.07,-1.07,12,-1.07,1.07,6,1.07,1.07
  63. 720  DATA 11,0,-.95,13,-.95,0,7,.95,0,14,0,.95